home *** CD-ROM | disk | FTP | other *** search
/ Gold Medal Software 2 / Gold Medal Software Volume 2 (Gold Medal) (1994).iso / prog / asm_n_z.arj / TSRSH.ASM < prev    next >
Assembly Source File  |  1987-02-02  |  27KB  |  1,100 lines
  1. PAGE    60,132
  2. TITLE    Ram-Resident Program Shell, Preliminary Version (Lesson 2)
  3. SUBTTL    Date 02-02-87 -- Tutorial for Microsoft Forum  Version 0.03
  4. ;-----------------------------------------------------------------------------
  5. ;    Ram-Resident Program Shell
  6. ;
  7. ;
  8. ;The software, documentation and source code are: 
  9. ; 
  10. ;    (C) Copyright 1986, 1987
  11. ;    Chip Rabinowitz
  12. ;    All Rights Reserved 
  13. ; 
  14. ;    51 East Rogues Path
  15. ;    Huntington Station NY 11746
  16. ;    Assistant SysOp, Microsoft Forum, Compuserve PPN 76703,350
  17. ; 
  18. ; 
  19. ;COPYRIGHT NOTICE AND WARRANTY INFORMATION 
  20. ;----------------------------------------- 
  21. ; 
  22. ;This document ("the source code"), other accompanying written and disk-based
  23. ;notes and specifications ("the documentation"), and all referenced and related
  24. ;program files accompanying the source code and the documentation ("the
  25. ;software") are copyrighted by Chip Rabinowitz.  
  26. ;
  27. ;This program has been uploaded to Compuserve as part of a Tutorial in how
  28. ;to write Terminate-But-Stay-Resident programs, being conducted on
  29. ;Compuserve's Microsoft Special Interest Group during early 1987/
  30. ;
  31. ;This code (and all other code uploaded by the Copyright Holder as a 
  32. ;part of this TSR Tutorial) may be used with the following restrictions: 
  33. ;
  34. ;(1) If all or part of this code is used as part of a software package of 
  35. ;ANY kind, the following acknowledgement must be used in the Documentation 
  36. ;accompanying said package:
  37. ;
  38. ;    'Parts of the Resident Program Management for this Product are'
  39. ;    'Copyright (C) 1986, 1987 by Chip Rabinowitz, and are incorporated'
  40. ;    'into this product courtesy of the Ringmaster Development Team'
  41. ;
  42. ;(2) If all or part of this code is used as part of a software package that
  43. ;is placed in the public domain, no further restrictions apply.
  44. ;
  45. ;(3) If all or part of this code is used as part of a software package that
  46. ;is being distributed as 'shareware', a one-time-only donation of $10 will be
  47. ;accepted for the express purpose of continuing research into TSR standards.
  48. ;Note that this is a voluntary contribution, and should be sent to the
  49. ;Ringmaster Development Team at the address printed above.
  50. ;
  51. ;(4) If all or part of this code is used as part of a software package that
  52. ;will be distributed as a commercial product, a one-time-only payment of
  53. ;$25 will be accepted the express purpose of continuing research into TSR 
  54. ;standards.  Note that in THIS CASE ONLY, this is not a voluntary 
  55. ;contribution.  Commercial Developers are REQUIRED to make payment prior to
  56. ;incorporating these routines into their product.
  57. ;
  58. ;No copy of the source code may be distributed or given away without the
  59. ;accompanying documentation; and this notice must not be removed. 
  60. ; 
  61. ;There is no warranty of any kind associated with this software, and the
  62. ;copyright owner is not liable for damages of any kind.  By using this
  63. ;software, you agree to this. 
  64. ; 
  65. ;
  66.  
  67. XON     equ    11h
  68. XOFF    equ    13h
  69. TRUE    equ    1
  70. FALSE   equ    0
  71. CR    equ    0dh
  72. LF    equ    0ah
  73. TAB    equ    9
  74.  
  75.  
  76. HOTKEYON    equ    01h    ;hot key pressed
  77. SHIFTSON    equ    02h    ;shift states match
  78. TSRACTIVE    equ    04h    ;tsr is running in foreground
  79. INT28ACTIVE    equ    08h    ;INT28 routine is running in background
  80.  
  81. KB_DATA    equ    60h
  82. KB_CTL    equ    61h
  83. KB_FLG1    equ    17h
  84. KB_FLG2    equ    18h
  85. BIOS_DATA    equ    40h
  86.  
  87. code segment para public 'CODE'
  88.     org 100h
  89.     assume    cs:code, ds:code, es:code
  90. start:    jmp    begin
  91.  
  92.     db    1bh,'[2J'
  93. cpyrt    db    'Ram-Resident Program Shell, Preliminary Version (Lesson 2)',
  94.     db    CR,LF,LF
  95.     db    'Copyright (C) 1986, 1987 Chip Rabinowitz',
  96.     db    CR,LF,'All Rights Reserved',CR,LF,LF,'$'
  97. hello    db    'Hello World!',CR,LF,'$'
  98. bad_dos_msg    db    'Incompatible DOS version .... Aborting!',07h,CR,LF,'$'
  99.  
  100. tsr_parms:
  101.     PSP    dw    ?    ;PSP of TSR
  102.     OLDPSP    dw    ?    ;location to save current PSP
  103.     DTA    dd    ?    ;DTA of TSR
  104.     OLDDTA    dd    ?    ;location to save current DTA
  105.     DSEG    dw    ?    ;TSR's Data Segment
  106.     SSEG    dw    ?    ;TSR's Stack Segment ....
  107.     SPTR    dw    0fffeh    ;.... and Stack Pointer
  108.     ISSEG    dw    0    ;interrupted SS ...
  109.     ISPTR    dw    0    ;..... and SP
  110.     SHIFTST    db    0    ;Shift State to Activate
  111.     HOTKEY    db    0ffh    ;scan code to activate
  112.     STATUS    dw    0    ;current status words
  113.     POPUP    dd    0    ;far pointer to popup routine
  114.  
  115. intflags    db    0
  116. ININT13        equ    04h    ;Bios disk interrupt
  117. ININT21        equ    08h    ;DOS interrupt
  118.  
  119. dosversion    db    0    ;current version of DOS
  120. waitcount    db    0    ;wait to activate count
  121.  
  122. indosflag    dd    0    ;Pointer to INDOS flag
  123. doscriterr    dd    0    ;Pointer to DOS Critical Error Flag
  124.  
  125. dossseg        dw    0    ;pointer to dos stack segment
  126. dossptr        dw    0    ;pointer to dos stack pointer
  127. dossize        dw    0    ;dos stack size
  128.  
  129. dos21funcs    label    byte
  130.     db    0,    0,    0,    0,    0,    0,    0,    0    ;0-7
  131.     db    0,    0,    0,    0,    0,    0ffh,    0ffh,    0ffh    ;8-f
  132.     db     0ffh,    0ffh,    0ffh,    0ffh,    0ffh,    0ffh,    0ffh,    0ffh    ;10-17
  133.     db    0ffh,    0ffh,    0ffh,    0ffh,    0ffh,    0ffh,    0ffh,    0ffh    ;18-1f
  134.     db    0ffh,    0ffh,    0ffh,    0ffh,    0ffh,    0ffh,    0,    0ffh    ;20-27
  135.     db    0ffh,    0ffh,    0ffh,    0ffh,    0ffh,    0ffh,    0ffh,    0    ;28-2f
  136.     db    0ffh,    0,    0,    0,    0,    0,    0ffh,    0ffh    ;30-37
  137.     db    0ffh,    0ffh,    0ffh,    0ffh,    0ffh,    0ffh,    0ffh,    0ffh    ;38-3f
  138.     db    0ffh,    0ffh,    0ffh,    0ffh,    0ffh,    0ffh,    0ffh,    0ffh    ;40-47
  139.     db    0,    0,    0,    0,    0ffh,    0,    0ffh,    0ffh    ;48-4f **
  140.     db    0,    0,    0,    0,    0ffh,    0,    0ffh,    0ffh    ;50-57
  141.     db    0,    0ffh,    0ffh,    0ffh,    0ffh,    0ffh,    0,    0    ;58-5f
  142.     db    0ffh,    0ffh,    0ffh,    0ffh,    0ffh,    0ffh,    0ffh,    0ffh    ;60-67
  143.  
  144. ;
  145. ; ***************************************************************************
  146. ;    These are the bios interrupt vectors
  147. ;
  148.  
  149. BIOSI8    equ    08h        ;Bios Timer interrupt
  150. BIOSI9    equ    09h        ;BIOS Hardware Keyboard interrupt
  151. BIOSIB    equ    0Bh
  152. BIOSIC    equ    0Ch
  153. BIOSI10    equ    10h
  154. BIOSI13    equ    13h        ;Bios Disk interrupt
  155. BIOSI14    equ    14h
  156. BIOSI15    equ    15h
  157. BIOSI16    equ    16h        ;Bios Keyboard interrupt
  158. BIOSI17    equ    17h
  159. BIOSI1C    equ    1Ch
  160. DOSI21    equ    21h        ;DOS service router interrupt
  161. DOSI28    equ    28h        ;DOS Idle interrupt
  162. DOSI33    equ    33h        ;mouse interrupt
  163. BIOSI1B    equ    1Bh
  164. DOSI23    equ    23h
  165. DOSI24    equ    24h
  166. ;
  167. oldint8        dd    0    ;BIOS Hardware Timer Interrupt
  168.         db    BIOSI8
  169.         dw    offset newint8    ;replacement vector
  170. oldint9        dd    0    ;BIOS Hardware Keyboard Interrupt
  171.         db    BIOSI9
  172.         dw    offset newint9    ;replacement vector
  173. oldint13    dd    0    ;BIOS Disk Interrupt
  174.         db    BIOSI13
  175.         dw    offset newint13    ;replacement vector
  176. oldint16    dd    0    ;BIOS Software Keyboard Interrupt
  177.         db    BIOSI16
  178.         dw    offset newint16    ;replacement vector
  179. oldint21    dd    0    ;DOS Services Interrupt
  180.         db    DOSI21
  181.         dw    offset newint21    ;replacement vector
  182. oldint28    dd    0    ;DOS Idle Interrupt
  183.         db    DOSI28
  184.         dw    offset newint28    ;replacement vector
  185. oldint1B    dd    0    ;control-C vector
  186.         db    BIOSI1B
  187.         dw    offset intret    ;replacement vector
  188. oldint23    dd    0    ;control-C vector
  189.         db    DOSI23
  190.         dw    offset intret    ;replacement vector
  191. oldint24    dd    0    ;critical error vector
  192.         db    DOSI24
  193.         dw    offset newint24    ;replacement vector
  194.  
  195. ;
  196. ; ***************************************************************************
  197. ;    Function to restore interrupts.
  198. ;
  199. ;    If AX=0, this function does popup-interrupts (1B, 23 and 24)
  200. ;    If AX=anything else, this function does initial interrupts
  201. ;
  202. restore_int proc near
  203.     push    ds
  204.     push    ax
  205.     push    dx
  206.     push    si
  207.     push    di
  208.     push    cx
  209.     mov    di,7            ;7 bytes per structure
  210.  
  211.     or    ax,ax
  212.     jnz    restore1
  213.  
  214.     mov    cx,3            ;three times through
  215.     mov    si,offset oldint1B    ;start at table beginning
  216.     jmp    restore_loop
  217. restore1:
  218.     mov    cx,06h            ;six interrupts!
  219.     mov    si,offset oldint8    ;top of table
  220.  
  221. restore_loop:
  222.     push    cx
  223.     push    di            ;save structure size
  224.     push    ds
  225.     mov    al,4[si]        ;interrupt number
  226.     mov    dx,[si]            ;IP of interrupt vector
  227.     mov    ds,2[si]        ;CS of interrupt vector
  228.     mov    ah,25h            ;set interrupt vector function
  229.     int    21h
  230.     pop    ds
  231.     xor    ax,ax            ;clear this entry from table
  232.     mov    [si],ax            ;so it shows not used
  233.     mov    2[si],ax
  234.     pop    di            ;get size back
  235.     add    si,di            ;do it again
  236.     pop    cx
  237.     loop    restore_loop
  238.  
  239.     pop    cx
  240.     pop    di
  241.     pop    si
  242.     pop    dx
  243.     pop    ax
  244.     pop    ds
  245.     ret
  246. restore_int endp
  247. ;
  248. ; ***************************************************************************
  249. ;    Function to set interrupts.
  250. ;
  251. ;    If AX=0, this function does popup-interrupts (1B, 23 and 24)
  252. ;    If AX=anything else, this function does initial interrupts
  253. ;
  254. setup_int proc near
  255.     push    es
  256.     push    ax
  257.     push    bx
  258.     push    dx
  259.     push    di
  260.     push    si
  261.     push    cx
  262.     mov    di,7            ;7 bytes per structure
  263.  
  264.     or    ax,ax
  265.     jnz    setup1
  266.  
  267.     mov    cx,3            ;three times through
  268.     mov    si,offset oldint1B    ;start at table beginning
  269.     jmp    setup_loop
  270. setup1:
  271.     mov    cx,06h            ;six interrupts!
  272.     mov    si,offset oldint8    ;top of table
  273.  
  274. setup_loop:
  275.     push    cx
  276.     push    di            ;save structure size
  277. ;    push    ds
  278.  
  279.     mov    ax,[si]            ;check for value
  280.     or    ax,ax            ;if not zero, next one
  281.     jnz    setup2
  282.     mov    al,4[si]        ;interrupt number
  283.     mov    ah,35h            ;get interrupt vector function
  284.  
  285.     int    21h
  286. ;    pop    ds
  287.     mov    [si],bx            ;save IP
  288.     mov    2[si],es        ;save CS
  289.  
  290.     mov    al,4[si]        ;interrupt number
  291.                     ;DS already contains correct segment
  292.     mov    dx,5[si]        ;IP of interrupt vector
  293.     mov    ah,25h            ;set interrupt vector function
  294.     int    21h
  295.  
  296. setup2:
  297.     pop    di            ;get size back
  298.     add    si,di            ;do it again
  299.     pop    cx
  300.     loop    setup_loop
  301. ex_set:
  302.     pop    cx
  303.     pop    si
  304.     pop    di
  305.     pop    dx
  306.     pop    bx
  307.     pop    ax
  308.     pop    es
  309.     ret
  310. setup_int endp
  311.  
  312. setdta    macro    ddptr
  313.     push    ds
  314.     mov    ax,1a00h    ;Function used to get current DTA address }
  315.     mov    dx,word ptr ddptr    ;Offset of DTA returned }
  316.     mov    ds,word ptr ddptr+2    ;Segment of DTA returned by DOS }
  317.     int    21h        ;Execute MSDos function request }
  318.     pop    ds
  319.     endm
  320.  
  321. getdta    macro    ddptr
  322.     push    es
  323.     mov    ax,2f00h    ;Function used to get current DTA address }
  324.     int    21h        ;Execute MSDos function request }
  325.     mov    word ptr ddptr+2,es        ;Segment of DTA returned by DOS }
  326.     mov    word ptr ddptr,bx        ;Offset of DTA returned }
  327.     pop    es
  328.     endm
  329.  
  330. ;
  331. ; ***************************************************************************
  332. ;    S E T   P S P
  333. ;
  334. ;    A bug in DOS 2.0, 2.1, causes DOS to clobber its standard stack   }
  335. ;    Then the PSP get/set functions are issued at the DOS prompt. The  }
  336. ;    following checks are made, forcing DOS to use the "critical"      }
  337. ;    stack when the TSR enters at the INDOS level.                     }
  338. ;
  339. ;        BX contains the PSP segment to set
  340. ;
  341. setpsp    proc    near
  342.     call    checkindos        ;If Version < 3, and INDOS,...
  343.     jz    do_set_psp
  344.     mov    byte ptr es:[di],0ffh    ;set critical flag
  345.  
  346.  
  347. do_set_psp:
  348.     mov    ax,5000h        ;set PSP* function
  349.                     ;BX already holds segment
  350.     int 21h                ;DOS function request
  351.  
  352.     call    checkindos        ;If Version < 3, and INDOS,...
  353.     jz    set_out
  354.     mov    byte ptr es:[di],0h    ;set critical flag
  355.  
  356. set_out:
  357.     ret
  358.  
  359. setpsp    endp
  360.  
  361. ;
  362. ; ***************************************************************************
  363. ;    G E T   P S P
  364. ;
  365. ;    A bug in DOS 2.0, 2.1, causes DOS to clobber its standard stack   }
  366. ;    Then the PSP get/set functions are issued at the DOS prompt. The  }
  367. ;    following checks are made, forcing DOS to use the "critical"      }
  368. ;    stack when the TSR enters at the INDOS level.                     }
  369. ;
  370. ;        The PSP Segment is returned in BX
  371. ;
  372. getpsp    proc    near
  373.     call    checkindos        ;If Version < 3, and INDOS,...
  374.     jz    do_get_psp
  375.     mov    byte ptr es:[di],0ffh    ;set critical flag
  376.  
  377. do_get_psp:
  378.     mov    ax,5100h        ;get PSP function
  379.     int 21h                ;DOS function request
  380.                     ;BX now holds PSP segment
  381.     call    checkindos        ;If Version < 3, and INDOS,...
  382.     jz    get_out
  383.     mov    byte ptr es:[di],0h    ;clear critical flag
  384.  
  385. get_out:
  386.     ret
  387.  
  388. getpsp    endp
  389.  
  390. ;
  391. ; ***************************************************************************
  392. ;    This routine checks the version of DOS in use, and returns the
  393. ;    ZF=0 (Not zero) if version < 3.0, and INDOS is set.  Internal function
  394. ;    is called ONLY by getpsp and setpsp.
  395. ;
  396. checkindos proc near
  397.     mov    al,dosversion
  398.     cmp    al,3            ;If Version is less than 3.0 ...
  399.     jge    ok_ret
  400.     mov    es,word ptr indosflag+2    ; ... and ...
  401.     mov    di,word ptr indosflag
  402.     mov    al,byte ptr es:[di]
  403.     or    al,al            ;INDOS is set ...
  404.     jz    ok_ret
  405.     mov    es,word ptr doscriterr+2; ... then ...
  406.     mov    di,word ptr doscriterr
  407.     jmp    fixit            ;exit with not zero
  408. ok_ret:
  409.     xor    al,al            ;set zero flag
  410. fixit:
  411.     ret
  412.  
  413. checkindos endp
  414.  
  415. ;
  416. ; ***************************************************************************
  417. ;    Internal routine to establish addressibility of the data segment
  418. ;
  419. dds proc near
  420.     push    cs
  421.     pop    ds
  422.     ret
  423. dds endp
  424.  
  425. newint9 proc far
  426.  
  427. ;NOTE:  None of this pusing/popping is really necessary for THIS particular
  428. ;TSR, so I;ve commented it out.
  429. ;
  430. ;    pushf
  431. ;    cli
  432. ;    push    ds
  433. ;    push    es
  434. ;    push    ax
  435. ;    push    bx
  436. ;    push    cx
  437. ;    push    dx
  438. ;    push    di
  439. ;    push    si
  440.  
  441. ;    push    cs
  442. ;    pop    ds
  443.  
  444. ;internal INT9 processing here
  445.  
  446. ;getkey_out:
  447. ;    pop    si
  448. ;    pop    di
  449. ;    pop    dx
  450. ;    pop    cx
  451. ;    pop    bx
  452. ;    pop    ax
  453. ;    pop    es
  454. ;    pop    ds
  455. ;out_9:
  456. ;    popf
  457.  
  458. ;    cli
  459.     jmp    dword ptr cs:oldint9
  460.  
  461.  
  462. ;
  463. ; ***************************************************************************
  464. ;    This is the int return (IRET) dummy pointer 
  465. ;
  466. intret:
  467.     iret
  468.  
  469. ;This routine will be used at some future point ... commented out for now.
  470. ;
  471. ;ignore_9:
  472. ;    in    al,60h
  473. ;    push    ax
  474. ;    pop    ax
  475. ;    in    al,61h
  476. ;    mov    ah,al
  477. ;    or    al,80h
  478. ;    out    61h,al
  479. ;    xchg    ah,al
  480. ;    out    61h,al
  481. ;    mov    al,20h
  482. ;    out    20h,al
  483. ;    pop    ax
  484. ;    jmp    short out_9
  485.  
  486. newint9 endp
  487.  
  488. new_bios_flag    db    0
  489.  
  490. newint16 proc far
  491. start_again:
  492.     cmp    ah,00        ;if char request,
  493.     je    func00        ;loop for character
  494.     cmp    ah,01        ;if character availability test
  495.     je    func01        ;go check for char
  496.     push    ax
  497.     and    ah,10h        ;test for extra bios
  498.     pop    ax
  499.     jz    gobios16
  500.     mov    cs:new_bios_flag,10h
  501.     and    ah,3
  502.     jmp    short start_again
  503. gobios16:
  504.     or    ah,cs:new_bios_flag
  505.     jmp    dword ptr cs:[oldint16]
  506.                 ;go to bios interrupt 16
  507. func01:
  508.     push    ds
  509.     push    si
  510.     push    di
  511.     call    dds
  512. func01A:
  513.     call    keystat        ;look at key buffer
  514.     pushf            ;save return flags
  515.     jz    fret01        ;return if no key
  516.     call    hotcheck    ;test for hot key
  517.     jnz    fret01        ;not there
  518.     popf            ;flags back for loop
  519.     jmp    func01A        ;it was a hot key -- skip it!
  520. fret01:
  521.     mov    new_bios_flag,0
  522.     popf            ;flags back
  523.     pop    di
  524.     pop    si
  525.     pop    ds
  526.     ret    2        ;return to user
  527. func00:
  528.     push    ds
  529.     push    si
  530.     push    di
  531.     call    dds
  532. func00A:
  533.     call    keystat        ;wait until character available
  534.     jz    func00A        ;loop it
  535.     call    hotcheck    ;test for a hot key
  536.     jz    func00A        ;it sure was -- start loop again
  537.  
  538. b_func0:
  539.     mov    ah,0        ;get the next user key
  540.     or    ah,new_bios_flag
  541.     pushf            ;simulate it ...
  542.     call    dword ptr cs:oldint16    ;do bios
  543.  
  544. func_out:
  545.     pushf            ;save return flags
  546.     jmp    fret01        ;restore and return
  547.  
  548. newint16 endp
  549.  
  550. ;
  551. ;       call the background task if no key is available
  552. ;
  553. keystat proc near
  554.                 ;preserves all registers except
  555.                 ;AX,SI,DI,DS & flags
  556.     push    cx
  557.     push    bx
  558.  
  559.     push    ax
  560.     push    ds
  561.     cld
  562.  
  563.     mov    ax,BIOS_DATA
  564.     mov    ds,ax        ;set data segment
  565.     mov    si,KB_FLG1    ;set source
  566.  
  567.     lodsw            ;get the high and low bytes
  568.     pop    ds
  569.     mov    bx,ax        ;save it away
  570.     pop    ax
  571.  
  572.  
  573.     mov    al,SHIFTST    ;shift state check
  574.  
  575.     or    al,al        ;is it zero?
  576.     jz    sim_16        ;yes -- set flag for simulation
  577.  
  578.     push    bx        ;save current flags
  579.     and    bl,al        ;mask bits
  580.     cmp    al,bl        ;are we the same?
  581.     pop    bx
  582.     jne    skip_16A    ;nope -- next one
  583. sim_16:
  584.     or    word ptr STATUS,SHIFTSON    ;set the flag
  585.  
  586.     mov    al,HOTKEY    ;is this control block the last one?
  587.  
  588.     or    al,al
  589.     jnz    short skip_16
  590.     or    word ptr STATUS,HOTKEYON    ;turn on hotkey flag
  591.     jmp    short skip_16
  592. skip_16A:
  593.     and    word ptr STATUS,NOT SHIFTSON    ;set the flag
  594.  
  595. skip_16:
  596.     mov    ah,1            ;see if character is available
  597.     or    ah,new_bios_flag
  598.     pushf                ;simulate interrupt
  599.     call    dword ptr cs:oldint16
  600.  
  601.     jnz    exit_161        ;got one
  602.  
  603. chkdos_161:
  604.     cld
  605.     push    ds            ;check if dos critical error in effect
  606.     push    si
  607.         lds     si,cs:doscriterr    ;zero says dos is interruptable
  608.     lodsb                ;$ff  says dos is in a critical state
  609.     lds     si,cs:indosflag        ;if indos then int $28 issued by dos
  610.     or    al,[si]            ;so we dont have to.
  611.                     ;account for active interrupts
  612.     or    al,cs:intflags        ;any flags says we dont issue call
  613.     pop    si            ;to the background.
  614.     pop    ds
  615.     cmp    al,01            ;must be indos flag only
  616.     jg    skip28            ;dos cannot take an interrupt yet
  617.     int    28h            ;call dos idle function (background dispatch).
  618. skip28:
  619.     xor    ax,ax            ;show  no keycode available
  620. exit_161:
  621.     pop    bx
  622.     pop    cx
  623.         ret
  624.  
  625. keystat    endp
  626.  
  627. hotcheck proc near    ;DI points to TSR Block character is from
  628.             ;SI holds ID of TSR routine
  629.  
  630.     push    cx
  631.     push    ax        ;save character
  632.     push    di
  633.  
  634.     mov    al,HOTKEY
  635.  
  636.     or    al,al
  637.     jz    only_shift    ;special case for shift-state only
  638.  
  639.     cmp    al,ah        ;do scan codes match?
  640.     jne    again_16H
  641.  
  642. only_shift:
  643.     push    ax
  644.     mov    ax,STATUS    ;get TSR status flags
  645.     test    ax,SHIFTSON    ;are shift codes set?
  646.     jz    again_16H1    ;nope -- try next one
  647.     
  648.     or    ax,HOTKEYON    ;turn on hotkey flag
  649.     mov    STATUS,ax    ;put new flags back
  650.  
  651.     pop    ax
  652.     or    al,al        ;test for special case
  653.     pop    di        ;get back Block pointer
  654.     pop    ax        ;throwing this away
  655.  
  656.     jz    hot_out        ;special case for flags only
  657.  
  658. b_func1:
  659.     mov    ah,0        ;get rid of the character
  660.     or    ah,new_bios_flag
  661.     pushf            ;simulate interrupt
  662.     call    dword ptr cs:oldint16    ;do bios
  663.  
  664. hot_out:
  665.     xor    ax,ax        ;set zero flag
  666.     jmp    got_hot
  667.  
  668. again_16H1:
  669.     pop    ax        ;get rid of flag
  670. again_16H:
  671.     mov    al,0ffh
  672.     or    al,al        ;clear zero flag if set
  673.     pop    di
  674.     pop    ax        ;get back keystroke
  675. got_hot:
  676.     pop    cx        ;get back cx register
  677.     ret
  678.  
  679. hotcheck endp
  680.  
  681. newint8 proc far
  682.  
  683.     pushf
  684.     push    ds
  685.     push    di
  686.     push    cx            ;save regs
  687.     push    ax
  688.     call    dds
  689.  
  690.     mov    ax,STATUS
  691.     test    ax,HOTKEYON    ;is hot-key flag set?
  692.     jz    again_8_2
  693.     test    ax,TSRACTIVE    ;are we already running?
  694.     jnz    again_8_2    ;yep -- next one
  695.  
  696. wait_8:
  697.     cmp    waitcount,0    ;if waiting, check time
  698.     jnz    wait2_8        ;decrement count
  699.  
  700. chkdos_8:
  701.     cld
  702.     push    ds            ;check if dos critical error in effect
  703.     push    si
  704.         lds     si,cs:doscriterr    ;zero says dos is interruptable
  705.     lodsb                ;$ff  says dos is in a critical state
  706.     lds     si,cs:indosflag        ;add in second status byte
  707.     or    al,[si]
  708.     or    al,cs:intflags        ;any flags says we're busy
  709.     pop    si
  710.     pop    ds
  711.     jnz    wait1_8            ;we're busy -- set count & EXIT
  712.     call    dopopup            ;call the popup stuff
  713.     jmp    end_8            ;and out we go
  714. wait1_8:
  715.     mov    waitcount,10h        ;set the count
  716. wait2_8:
  717.     dec    waitcount
  718.     jz    chkdos_8
  719.  
  720. again_8_2:
  721. end_8:
  722.     pushf                ;simulate interrupt ...
  723.     call dword ptr oldint8        ;do the original
  724.  
  725.     pop    ax        ;get back registers
  726.     pop    cx
  727.     pop    di
  728.     pop    ds
  729.     popf
  730.  
  731. exit_8:
  732.     iret
  733.  
  734. newint8 endp
  735.  
  736. newint28 proc far
  737.  
  738.     pushf                ;simulate interrupt ...
  739.     call dword ptr cs:oldint28    ;do the original
  740.  
  741.     push    ds
  742.     push    di
  743.     push    cx            ;save regs
  744.     push    ax
  745.  
  746.     push    cs
  747.     pop    ds
  748.  
  749. again_28:
  750.     mov    ax,STATUS    ;get TSR status flags
  751.     test    ax,HOTKEYON    ;is hot-key flag set?
  752.     jz    again_28_2
  753.     test    ax,TSRACTIVE    ;are we already running?
  754.     jnz    again_28_2    ;yep -- next one
  755.  
  756. chkdos_28:
  757.     cld
  758.     push    ds            ;check if dos critical error in effect
  759.     push    si
  760.         lds     si,cs:doscriterr    ;zero says dos is interruptable
  761.     lodsb                ;$ff  says dos is in a critical state
  762.     or    al,cs:intflags        ;any flags says we're busy
  763.                     ;NOTE:  Indos flag is always set here!
  764.                     ; ... so don't have to check it!
  765.     pop    si
  766.     pop    ds
  767.     jnz    end_28            ;we're busy-EXIT & try again next time
  768.  
  769.     mov    waitcount,0        ;clear waiting count and ...    
  770.     call    dopopup            ;... call the popup stuff
  771.     jmp    end_28            ;and out we go
  772.  
  773. again_28_2:
  774. end_28:
  775.     pop    ax        ;get back registers
  776.     pop    cx
  777.     pop    di
  778.     pop    ds
  779.  
  780. exit_28:
  781.     iret
  782.  
  783. newint28 endp
  784.  
  785. di28    dw    0
  786. ds28    dw    0
  787.  
  788. dopopup proc near
  789.  
  790.     cli            ;no interrupts now!!!
  791.     
  792.     or    word ptr STATUS,TSRACTIVE    ;set active bit
  793.  
  794.     mov    ISSEG,ss        ;save user's stack segment
  795.     mov    ISPTR,sp        ;... and stack pointer
  796.                     ;DS was saved in INT8 or INT28
  797.  
  798.     mov    ss,SSEG        ;load TSR stack segment ...
  799.     mov    sp,SPTR        ;... and stack pointer
  800.  
  801.     push    bp            ;save all registers except for
  802.     push    bx            ;...those saved by calling routine,
  803.     push    dx            ;...DS,DI,CX,AX are restored on exit
  804.     push    si            ;...from this procedure
  805.     push    es
  806.  
  807.     mov    [di28],di        ;save TSR pointer until after saving
  808.     mov    [ds28],ds        ;...Indos stack
  809.  
  810.     mov    di,sp            ;destination is our stack
  811.     dec    di
  812.     dec    di            ;back off current word
  813.     mov    ax,ss            ;move stack segment
  814.     mov    es,ax            ;...to extra segment
  815.  
  816.     mov    si,cs:dossptr        ;source is DOS Indos Primary Stack
  817.     mov    ds,cs:dossseg        ;...and segment, of course
  818.     dec    si            ;point to last word on DOS stack
  819.     dec    si
  820.  
  821.     mov    cx,40h            ;stack size to save
  822.  
  823.     mov    ax,sp            ;save current stack pointer ...
  824.     sub    ax,cx            ;...and make room to avoid
  825.     sub    ax,cx            ;...overwriting during REP
  826.     mov    sp,ax            ;...and put it back
  827.  
  828.     std                ;set the direction flag ...
  829.     rep    movsw            ;and move the 40 word stack
  830.     mov    sp,di
  831.     cld                ;direction flag back
  832.  
  833.     mov    di,cs:di28        ;get TSR pointer back
  834.     mov    ds,cs:ds28
  835.  
  836.     sti                ;interrupts back on!!
  837.  
  838.     getdta    OLDDTA            ;save current DTA
  839.  
  840.     call    getpsp            ;get current PSP segment
  841.     mov    OLDPSP,bx        ;...returned in BX
  842.  
  843.     mov    bx,PSP            ;set TSR's PSP in BX
  844.     call    setpsp            ;...and do it
  845.  
  846.     setdta    DTA
  847.  
  848.     xor    ax,ax
  849.     call    setup_int        ;replace with our handler
  850.  
  851.     push    ds            ;save DS:DI for after popup
  852.     push    di
  853.     mov    ds,DSEG        ;load user's data segment
  854.  
  855.  
  856.     call    dword ptr cs:POPUP    ;call the user routine!!
  857.  
  858.  
  859.     pop    di            ;restore ds:di for addressibility
  860.     pop    ds
  861.  
  862.     mov    bx,OLDPSP        ;replace interrupted PSP
  863.     call    setpsp
  864.  
  865.     setdta    OLDDTA        ;restore interrupted DTA
  866.  
  867.     xor    ax,ax
  868.     call    restore_int        ;restore interrupts as well
  869.  
  870. ;terminate checking here!
  871.  
  872.     cli                ;no interrupts while manipulating stack
  873.  
  874.     mov    cx,40h            ;stack size here
  875.  
  876.     mov    di28,di            ;save TSR pointer until after saving
  877.     mov    ds28,ds            ;...Indos stack
  878.  
  879.     mov    ax,ss            ;source is current stack
  880.     mov    ds,ax
  881.     mov    si,sp            ;point to last word on our stack
  882.     inc    si
  883.     inc    si
  884.  
  885.     mov    es,cs:dossseg        ;destination is dos stack
  886.     mov    di,cs:dossptr
  887.     sub    di,cx            ;point backward to last used word 
  888.     sub    di,cx            ;...on dos stack
  889.     cld
  890.     rep    movsw
  891.  
  892.     mov    sp,si            ;skip over moved words
  893.  
  894.     mov    di,cs:[di28]        ;get TSR pointer back
  895.     mov    ds,cs:[ds28]
  896.  
  897.     pop    es
  898.     pop    si
  899.     pop    dx
  900.     pop    bx
  901.     pop    bp
  902.  
  903. ;
  904. ; ***************************************************************************
  905. ;
  906. ;    CAUTION!!!! THE USER ROUTINE MUST RETURN SS:SP WITH THE SAME
  907. ;        VALUES AS ON ENTRY.  OTHER REGISTERS WILL BE RESTORED
  908. ;        BY THIS ROUTINE.
  909. ;
  910. ; ***************************************************************************
  911. ;
  912. back_popup:
  913.  
  914.     mov    ss,ISSEG        ;restore user's stack segment
  915.     mov    sp,ISPTR        ;... and stack pointer
  916.                     ;DS will be restored in INT8 or INT28
  917.     and    STATUS,NOT HOTKEYON+TSRACTIVE
  918.                     ;clear hot-key and inuse bits
  919.  
  920.     sti                ;enable interrupts again
  921. dopopup_end:
  922.     ret
  923.  
  924. dopopup endp
  925.  
  926. newint13 proc far
  927.  
  928.     pushf
  929.     or     cs:intflags,ININT13
  930.     popf            ;get back original flags
  931.  
  932.     pushf                ;simulate interrupt ...
  933.     call dword ptr cs:oldint13    ;do the original
  934.  
  935.     pushf
  936.     and    cs:intflags,NOT ININT13
  937.     popf
  938.  
  939.     ret    2
  940.  
  941. newint13 endp
  942.  
  943. newint21 proc far
  944.     pushf
  945.     sti                ;allow interrupts
  946.  
  947.     cmp    ah,63h            ;max number
  948.     jg    notme
  949.     push    ax            ;some INT21 functions must be left
  950.     push    bx            ;...alone.  They either never return,
  951.     mov    bx,offset dos21funcs    ;...grab parameters from the stack
  952.     mov    al,ah            ;...or can be interrupted.
  953.     xlat    cs:dos21funcs        ;test function against table
  954.     or    al,al            ;wait for functions marked zero
  955.     pop    bx            ;these ,ust be left alone
  956.     pop    ax
  957.     jz    notme            ;jump to original INT21
  958.     jmp    short set_21
  959. notme:
  960.     popf
  961.     jmp    dword ptr cs:oldint21
  962.  
  963. set_21:
  964.     or     cs:intflags,ININT21    ;say int21 is active
  965.     popf                ;get original flags back
  966.     pushf                ;save flags and all regs that
  967.  
  968.     call    dword ptr cs:oldint21    ;do the interrupt
  969.     sti
  970.  
  971.     pushf                ;save return registers
  972.     and    cs:intflags,NOT ININT21    ;not active any more
  973.     popf                ;they're back
  974.  
  975.     ret    2            ;return with flags set
  976.  
  977. newint21 endp
  978.  
  979. error24    dw    0
  980.  
  981. newint24 proc far
  982.     pushf
  983.     mov    cs:error24,di        ;save the error
  984.     mov    al,0
  985.     iret
  986. newint24 endp
  987.  
  988. pop_routine proc far    ;just prints a msg and gets out
  989.     lea    dx,hello
  990.     mov    ah,9
  991.     int    21h        ; display copyright notice
  992.     ret
  993. pop_routine endp
  994.  
  995.  
  996. TSR_stack     db    512 dup(0)
  997. TSR_stack_end:
  998.  
  999. res_part:    ; this is the end of my resident code so I can tell DOS
  1000.         ; how big I am
  1001. ;
  1002. ;
  1003. ; ***************************************************************************
  1004. ;
  1005. ;    Initialization Code -- load routine and point new int14
  1006. ;
  1007. second_time    db    0    ;flag used to test for odd-byte check
  1008.  
  1009. begin:
  1010.     lea    dx,cpyrt
  1011.     mov    ah,9
  1012.     int    21h        ; display copyright notice
  1013.  
  1014.     call    getpsp        ;Current PSP returned in BX
  1015.     mov    PSP,bx
  1016.     getdta    DTA        ;macro to get Disk Transfer Address
  1017.  
  1018.     mov    ax,ds
  1019.     mov    DSEG,ax        ;save it
  1020.     mov    SSEG,ax        ;save it here too!
  1021.     mov    word ptr POPUP+2,ax    ;save it here three!
  1022.     mov    ax,offset TSR_stack_end
  1023.     sub    ax,2
  1024.     mov    SPTR,ax
  1025.  
  1026.     mov    SHIFTST,08h    ;ALT-Key + ...
  1027.     mov    HOTKEY,2dh    ;...'X' to pop up
  1028.  
  1029.     mov    word ptr POPUP,offset pop_routine
  1030.  
  1031.     mov    ax,3400h        ;find the DOS Indos Byte
  1032.     int    21h
  1033. ;IF SOMEBODY HAS AT&T DOS 2.11, would you please try something?
  1034. ;
  1035. ;Move the label 'crit2' to the second location (where it is currently)
  1036. ;commented out, and see how it works.  There is still some dissension
  1037. ;about where the critical byte actually is in that version of DOS!
  1038.  
  1039. crit2:
  1040.     mov    word ptr indosflag,bx    ;offset returned in BX
  1041.     mov    word ptr indosflag+2,es    ;segment returned in ES
  1042.     mov    dossseg,es        ;this is also the DOS stack segment
  1043.     mov    word ptr doscriterr+2,es;as well as the segment for the critical flag
  1044. ;crit2:
  1045.     mov    cx,2000h         ;search for instruction: CMP [crit flag],00
  1046.     mov    ax,3e80h         ;3e80 is opcode to search for
  1047.     mov    di,bx             ;start search here
  1048. crit3:
  1049.     repnz    scasw             ;search until a match is found
  1050.     jnz    no_crit_found         ;couldn't find critical byte
  1051.                     ;we're going to search for the
  1052.                     ;address of the critical flag
  1053.                     ;es:[di-2] now points to:
  1054.                     ;       CMP [crit flag],00
  1055.                     ;       JNZ ...
  1056.                     ;       MOV SP,indos stack address      
  1057.     mov    al,byte ptr es:[di+5]     ;MOV SP,xxxx
  1058.     cmp    al,0bch         ;opcode for MOV SP
  1059.     jne    crit3             ;bad place.  Sorry
  1060.     mov    ax,word ptr es:[di]     ;here's the critical byte address
  1061.     mov    word ptr doscriterr,ax
  1062.     mov    ax,word ptr es:[di+6]     ;...and here's the stack pointer
  1063.     mov    word ptr dossptr,ax
  1064.     mov    ax,1                                                     
  1065.     jmp    no_error
  1066. no_crit_found:
  1067.     mov    al,second_time        ;did we already try odd bytes?
  1068.     or    al,al
  1069.     jz    crit_again        ;nope ...
  1070.     jmp    bad_dos_version        ;we tried!
  1071. crit_again:
  1072.     mov    second_time,1        ;set the flag
  1073.     inc    bx            ;increment pointer (needed for AT&T
  1074.     jmp    crit2            ;DOS 2.11 and some others
  1075.  
  1076. no_error:
  1077.     mov    ax,1
  1078.     call    setup_int
  1079.  
  1080.     lea    dx,res_part    ; load offset of top of code
  1081.     add    dx,15        ;round up
  1082.     shr    dx,1
  1083.     shr    dx,1
  1084.     shr    dx,1
  1085.     shr    dx,1        ; divide by 16 to get paragraphs
  1086.     xor    al,al        ; no errors
  1087.     mov    ah,31h        ; load terminate & stay resident code
  1088.     int    21h
  1089.  
  1090. bad_dos_version:
  1091.     lea    dx,bad_dos_msg
  1092.     mov    ah,9
  1093.     int    21h        ; display error message
  1094.     mov    ax,4cffh            ;exit with -1 return code
  1095.     int    21h
  1096.  
  1097. code    ends
  1098.  
  1099.     end    start
  1100.